0 REM THE TRANSACTOR VOLUME 6 ISSUE 02  PAGE 36
100 CLOSE 2:OPEN 2,2,0,CHR$(96+1)+CHR$(0)
110 REM C-64 ONLY:POKE 53280,0:POKE 53281,0:PRINT""
120 PRINT "[147]TDD TERM 60 WPM BAUDOT":PRINT "RX[146] ";
130 POKE 665,236:POKE 666,87:D=37136:REM IF C-64 THEN D=56577
140 LS=-1
150 LF$=CHR$(10)
160 CR$=CHR$(13)
170 L$="E"+LF$+"A SIU"+CR$+"DRJNFCKTZLWHYPQOBG*MXV*"
180 F$="3"+LF$+"- '87"+CR$+"$4',!:(5')2#6019?&*./;*"
190 L1$="CYNIAMZTFKOR\LXVWJEPG^S]UQ"
200 F1$="MDTIDZQORDDLC\]VWSAJPUGFXN^DDDYD"
210 GET#2,C$:IF C$="" THEN 270
220 C=ASC(C$):IF C<1 OR C>31 THEN 210
230 IF LS THEN C$=MID$(L$,C,1)
240 IF NOT LS THEN C$=MID$(F$,C,1)
250 IF C$<>"*" THEN PRINT C$;:GOTO 270
260 LS=(C=31)
270 GET A$:IF A$="" THEN 210
280 IF A$="[133]" THEN POKE D,96:GOTO 300
290 GOTO 210
300 PRINT "TX[146] ";
310 GET X$:IF X$="" THEN 310
320 IF X$=CHR$(34) THEN X$=CHR$(39)
330 IFX$="[133]"THENPRINT" GA ";:PRINT#2,"DZCD";:GOTO 350
340 GOTO 360
350 PRINT"RX[146] ";:GOSUB680:POKED,100:GOTO 210
360 IF X$="[134]" THEN M1$="RYRYRYRYRYRYRYRYRYRYRY ":GOTO 520
370 IF X$="[135]" THEN M1$="LISTING FOR J SMITH SPRINGFIELD IL PSE  ":GOTO 520
380 IF X$="[136]" THEN M1$="THANK YOU AND GOOD EVENING ":GOTO 520
390 PRINT X$;
400 IF X$=CR$ THEN PRINT#2,"H";:GOTO 310
410 IF X$=LF$ THEN PRINT#2,"B";:GOTO 310
420 IF X$=CHR$(32) THEN PRINT#2,"D";:GOTO 310
430 X=ASC(X$)
440 IF X<33 THEN GOTO 310
450 IF X<65 THEN X=X-32:GOTO 470
460 GOTO 480
470 X$=CHR$(91)+MID$(F1$,X,1):PRINT#2,X$+CHR$(95);:GOTO 310
480 IF X>95 THEN GOTO 310
490 X=X-64:X$=MID$(L1$,X,1)
500 PRINT#2,X$;
510 GOTO 310
520 FOR S=1 TO LEN(M1$)
530 X$=MID$(M1$,S,1)
540 PRINT X$;
550 IF X$=CR$ THEN PRINT#2,"H";:GOTO 660
560 IF X$=LF$ THEN PRINT#2,"B";:GOTO 660
570 IF X$=CHR$(32) THEN PRINT#2,"D";:GOTO 660
580 X=ASC(X$)
590 IF X<33 THEN PRINT#2,"D"
600 IF X<65 THEN X=X-32:GOTO 620
610 GOTO 630
620 X$=CHR$(91)+MID$(F1$,X,1):PRINT#2,X$+CHR$(95);:GOTO 660
630 IF X>95 THEN PRINT#2,"D";
640 X=X-64:X$=MID$(L1$,X,1)
650 PRINT#2,X$;
660 NEXT S
670 GOTO 310
680 FOR X=1TO1300:NEXT:RETURN
690 REM COPYRIGHT (C)
700 REM 1984 BY
710 REM JIM GRUBBS
720 REM PO BOX 3042
730 REM SPRINGFIELD
740 REM ILL 62708